/*
MainImporter.as
Hugh Elliott helliott@organic.com
version 2.1.0

Class to import single items whether xml, bitmap or swf

Copyright (c) 2008, Hugh Elliott

Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in
all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
THE SOFTWARE.

 dispatches event that whatever is loading has loaded.
 usage:
 itemImport = new MainImporter(tmpURL);
 itemImport.addEventListener(MainImporter.ITEMLOADED,itemLoaded);
 
 handling of loaded item, if bitmap
 var image:Bitmap = evt.target.loader.content as Bitmap;
 addChild(image);
 
 handling of loaded item, if swf
 var swffile:MovieClip = evt.target.loader.content as MovieClip;
 addChild(swffile);
 
 handling of loaded item, if xml
 var xmlItem:XML = new XML(evt.target.loaderXML.data);
 e4x handling of xml
 
 basic example with event handler
 xmlImport = new MainImporter(PRESENTATIONXML);
 xmlImport.addEventListener(MainImporter.ITEMLOADED,dealWithXML);
 private function dealWithXML(evt:Event):void{
	var xmlItem:XML = new XML(evt.target.loaderXML.data);
	trace(xmlItem);
 }			
 */
package com.utils{
	import com.events.LoaderEvent;
	import flash.display.Loader;
	import flash.events.Event;
	import flash.events.EventDispatcher;
	import flash.events.IOErrorEvent;
	import flash.events.ProgressEvent;
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	public class MainImporter extends EventDispatcher{
		public static const ITEMLOADED:String = "item loaded";
		private var itemURL:String;
		public var loader:Loader;
		public var loaderXML:URLLoader;
		private var fileEnder:String;
		public var loadedCurrent:Number;
		public var loadedTotal:Number;
		public function MainImporter(_url:String){
			itemURL = _url;
			var tmpArray:Array = itemURL.split(".");
			fileEnder = tmpArray[tmpArray.length-1];
			loadItem();
		}
		private function loadItem():void{
			var urlRequest:URLRequest = new URLRequest(itemURL);
			if(fileEnder == "xml"){
				loaderXML = new URLLoader();
				loaderXML.addEventListener(IOErrorEvent.IO_ERROR,loadError);
				loaderXML.addEventListener(ProgressEvent.PROGRESS,progressListener);
				loaderXML.addEventListener(Event.COMPLETE,completeLoad);
				loaderXML.addEventListener(Event.INIT,initListener);
				loaderXML.load(urlRequest);
			}else{
				loader = new Loader();
				loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR,loadError);
				loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS,progressListener);
				loader.contentLoaderInfo.addEventListener(Event.COMPLETE,completeLoad);
				loader.contentLoaderInfo.addEventListener(Event.INIT,initListener);
				loader.load(urlRequest);
			}
		}
		private function initListener(evt:Event):void{
			//trace("init");
		}
		private function progressListener(evt:ProgressEvent):void{
			loadedCurrent	=	Math.floor(evt.bytesLoaded/1024);
			loadedTotal		=	Math.floor(evt.bytesTotal/1024);
			dispatchEvent(new LoaderEvent(LoaderEvent.UPDATELOADER,loadedCurrent,loadedTotal,true));
		}
		private function loadError(evt:IOErrorEvent):void{
			trace("IOErrorEvent : " + evt);
		}
		private function completeLoad(evt:Event):void{
			dispatchEvent(new Event(MainImporter.ITEMLOADED));
		}
	}
}